La funzione SE Excel rappresenta, per molti professionisti, il vero spartiacque tra un utilizzo amatoriale e una gestione professionale dei fogli di calcolo. Non si tratta semplicemente di una formula, ma del primo passo verso l’automazione del lavoro: permette a Excel di prendere decisioni autonome basate su regole logiche predefinite.
Imparare a padroneggiare la funzione SE (nota come IF function nella versione inglese) significa smettere di controllare manualmente migliaia di righe e delegare al software il compito di verificare condizioni, assegnare categorie o calcolare risultati variabili.
In questa guida definitiva, analizzeremo la sintassi, le applicazioni aziendali, la gestione di scenari complessi con il se annidato excel e le moderne alternative come la funzione PIÙ.SE, fornendo gli strumenti necessari per costruire dashboard e report a prova di errore.
Samuele Agnolin — Docente Excel dal 2000. In oltre vent’anni ho insegnato queste formule a team di Louis Vuitton, Geox e Breton: la funzione SE è sempre il punto di partenza per trasformare un foglio passivo in uno strumento che ragiona al posto tuo.
Cos’è la funzione SE e a cosa serve
Dal punto di vista concettuale, la funzione SE introduce la logica decisionale all’interno di una cella. Il principio di funzionamento è binario e rispecchia il ragionamento umano: “Se si verifica una determinata condizione, esegui l’azione A; altrimenti, esegui l’azione B”.
Pensiamo a un’analogia con la vita reale: “Se piove, prendo l’ombrello; altrimenti, esco senza”. Excel applica esattamente questo schema ai dati. È fondamentale per l’automazione dei processi aziendali, come ad esempio:
– Verificare se un budget è stato superato.
– Applicare uno sconto solo a determinati clienti.
– Segnalare scadenze imminenti.
Senza la formula se excel, queste operazioni richiederebbero un controllo visivo riga per riga, con un elevato rischio di errore umano. Con la funzione attiva, il foglio di calcolo diventa dinamico: al variare dei dati in input, l’output si aggiorna istantaneamente seguendo la logica impostata.
Sintassi della funzione SE: come scriverla correttamente
Per scrivere una formula se robusta, è necessario comprendere a fondo la sua sintassi. In Excel, ogni funzione ha una struttura rigida che deve essere rispettata.
La struttura base è la seguente:
=SE(test; se_vero; se_falso)
Ecco un esempio pratico:
=SE(E2<=100;”Basso”;”Alto”)
I tre argomenti della funzione SE
Analizziamo nel dettaglio i tre argomenti che compongono la funzione:
- Test (o Test Logico): È la condizione che Excel deve verificare. Deve essere formulata in modo da restituire un risultato VERO o FALSO. Si utilizzano gli operatori di confronto come
=,>,<,>=,<=,<>. Esempio:D2 < 100(Il valore in D2 è minore di 100?). - Se_vero: È il valore o l’azione che Excel restituirà se il test logico risulta VERO. Può essere un numero, un testo, o anche un’altra formula.
- Se_falso: È il valore o l’azione che Excel restituirà se il test logico risulta FALSO.
Nota tecnica importante: In Italia, il separatore degli argomenti è il punto e virgola (;). Inoltre, se si desidera che la formula restituisca un testo, questo deve essere sempre racchiuso tra virgolette (es. "Obiettivo Raggiunto"). I numeri e i riferimenti di cella, invece, non richiedono virgolette.
Quando Se_vero o Se_falso non vengono specificati, il risultato sarà uno dei due valori logici VERO o FALSO.
Operatori di confronto disponibili
Nel test logico puoi usare sei operatori di confronto. Eccoli riepilogati con un esempio di formula per ciascuno:
| Simbolo | Significato | Esempio di formula |
|---|---|---|
= | Uguale a | =SE(A1=100;"Esatto";"No") |
<> | Diverso da | =SE(A1<>"attivo";"Inattivo";"Attivo") |
> | Maggiore di | =SE(A1>1000;"Sopra soglia";"Sotto soglia") |
< | Minore di | =SE(A1<0;"Negativo";"Positivo") |
>= | Maggiore o uguale a | =SE(A1>=18;"Maggiorenne";"Minorenne") |
<= | Minore o uguale a | =SE(A1<=100;"OK";"Superato") |
Come inserire la funzione SE dalla finestra guidata
Se preferisci inserire il SE utilizzando la finestra di inserimento dei parametri, ecco i passaggi:
- Posizionati sulla cella dove vuoi il risultato.
- Clicca sul pulsante Fx di inserimento funzioni e nella tipologia Logiche scegli il SE.
- Definisci il test e i parametri Se_vero e Se_falso.
Il SE appartiene alle funzioni logiche ed è tra le più utilizzate in assoluto. Si presta a risolvere tantissime situazioni che richiedono la verifica di una condizione.
Esempi pratici: casi d’uso in azienda
Ecco alcuni casi pratici di utilizzo della funzione SE, organizzati per tipologia. Ho scelto questi esempi perché rispecchiano le situazioni reali che incontro più spesso durante la formazione in azienda.
Esempi con testo (etichette e categorie)
Esempio 1 – Etichette genere
Vogliamo scrivere “Donna” quando la cella del genere riporta “F”, “Uomo” altrimenti.
=SE(B2="f";"Donna";"Uomo")
che potrebbe anche essere scritta in questo modo:
=SE(B2<>"f";"Uomo";"Donna")dove <>"f" significa diverso da “f”.
Esempio 2 – Stato completamento corso
Un dipendente supera il corso di sicurezza solo se il punteggio del test è maggiore o uguale a 60/100.
Formula: =SE(C2>=60;"Superato";"Non Superato")
Logica: qui utilizziamo stringhe di testo come output. È essenziale l’uso delle virgolette.
Esempio 3 – Recupero tipologia in base a codice
Se le ultime lettere del codice prodotto sono “FFF” allora il prodotto è una sedia, altrimenti è un tavolo.
=SE(DESTRA(B2;3)="fff";"sedia";"tavolo")Attenzione però: se avessimo un codice con tre numeri finali dobbiamo ricordare che la funzione DESTRA restituisce sempre un risultato testuale. Andrebbe quindi scritta così:
=SE(DESTRA(B2;2)="40";"sedia";"tavolo")oppure, per forzare la conversione a numero:
=SE(--DESTRA(B2;2)=40;"sedia";"tavolo")dove il -- davanti alla funzione DESTRA converte il risultato in numerico.
Esempi numerici (sconti, bonus, controlli)
Esempio 4 – Calcolo sconto
Vogliamo calcolare un importo scontato applicando uno sconto del 5% se il cliente ha speso meno di 100 euro, del 10% se ha speso da 100 in su.
=SE(B2<100;B2*0,95;B2*0,9)Esempio 5 – Calcolo bonus agente
Immaginiamo di dover calcolare le provvigioni. Se un agente ha venduto più di 50.000€, riceve un bonus del 5%; altrimenti il bonus è 0%.
Formula: =SE(B2>50000;B2*5%;0)
Logica: Excel controlla il fatturato in B2. Se supera la soglia, moltiplica quel valore per il 5%; in caso contrario, restituisce 0.
Esempio 6 – Verifica lunghezza codici prodotto
Vogliamo verificare la correttezza dei codici prodotto. Se la lunghezza del codice è pari a 9 il codice ha il numero esatto di cifre, altrimenti segnaliamo l’errore.
=SE(LUNGHEZZA(B2)=9;"ok";"codice errato")
Esempi con date e funzione OGGI()
Esempio 7 – Gestione scadenze fatture
Vogliamo verificare se una fattura è scaduta confrontando la data di scadenza con la data odierna.
Formula: =SE(D2<OGGI();"Scaduta";"In regola")
Logica: utilizziamo una funzione dinamica (OGGI()) all’interno del test logico. Se la data in D2 è precedente a oggi, la fattura è scaduta. Il foglio si aggiorna automaticamente ogni giorno senza intervento manuale.
Esempi con funzioni combinate (CERCA.VERT, DESTRA, LUNGHEZZA)
Esempio 8 – Rendere dinamica la matrice tabella di un CERCA.VERT
La funzione SE può essere utilizzata anche in combinazione con CERCA.VERT, e in più modi:
Per richiamare un CERCA.VERT piuttosto che un altro:
=SE(B2<100;CERCA.VERT(B2;K1:N500;2;0);CERCA.VERT(B2;P1:S500;3;0))Per modificare in maniera dinamica il riferimento alla matrice tabella:
=CERCA.VERT(B2;SE(B2<100;K1:N500;P1:S500);2;0)Questo approccio — SE annidato dentro CERCA.VERT — è uno degli usi più potenti della funzione e raramente trattato in altre guide.
Funzione SE con date
Quando utilizziamo nella funzione SE una data, può capitare di trovarci di fronte a una data memorizzata come testo: cosa che succede spesso quando il file proviene da un’esportazione di database. In questo caso dobbiamo convertire la data testuale attraverso la funzione DATA.VALORE, la quale converte una data in formato testo in un numero seriale (cioè una data riconosciuta da Excel), come indica anche la guida ufficiale Microsoft.
=SE(B2<DATA.VALORE("1/1/2016");"Pre 2016";"2016 o successivo")
E naturalmente possiamo fare riferimento senza problemi a una data scritta in una cella esterna:
=SE(B2<G$1;"Pre 2016";"2016 o successivo")Questa distinzione tra date testuali e date numeriche è un angolo che quasi nessuna guida tratta: è uno degli errori più frequenti che vedo nei file aziendali.
Funzione SE annidata: gestire più condizioni
La funzione SE in Excel può gestire fino a 64 condizioni annidate. Tuttavia, Microsoft sconsiglia di superare 3-4 livelli di annidamento perché la formula diventa difficile da leggere e manutenere. Per scenari con molte condizioni, è preferibile usare la funzione PIÙ.SE (disponibile da Excel 2019 e Microsoft 365).
Spesso la realtà aziendale non è bianca o nera (Vero/Falso), ma richiede più sfumature. Quando ci troviamo di fronte a una funzione SE con più condizioni, dobbiamo ricorrere al concetto di SE annidato Excel — chiamato anche SE annidata concatenata o SE concatenata nella terminologia comune.
Tecnicamente, questo significa inserire una seconda funzione SE all’interno dell’argomento se_falso della prima funzione SE. È come un sistema di “scatole cinesi”.
Esempio di scaglioni di prezzo:
- Quantità < 10: Prezzo 10€
- Quantità tra 10 e 50: Prezzo 8€
- Quantità > 50: Prezzo 5€
La formula sarà:
=SE(A1<10;10;SE(A1<=50;8;5))Come ragiona Excel:
- Controlla se A1 è minore di 10. Se sì, scrive 10 e si ferma.
- Se no, passa al secondo SE: controlla se A1 è minore o uguale a 50. Se sì, scrive 8.
- Se nessuna delle precedenti è vera, scrive 5.
Sebbene la funzione SE Excel con più condizioni sia potente, ha dei limiti di leggibilità. Creare formule con 7 o 8 livelli di SE annidata concatenata rende il file difficile da manutenere e prono a errori. In questi casi, è preferibile valutare funzioni alternative come CERCA.VERT o la più recente PIÙ.SE (te ne parlo nel paragrafo successivo).
Puoi approfondire questi concetti nel tutorial sui SE ANNIDATI.
SE con due condizioni: come usare SE+E e SE+O
Quando la condizione da verificare dipende da due criteri contemporaneamente, puoi combinare SE con le funzioni logiche E e O invece di annidare più SE.
SE+E restituisce VERO solo se tutte le condizioni sono soddisfatte contemporaneamente:
=SE(E(B2>50000;C2="Nord");"Bonus top";"Nessun bonus")In questo esempio il bonus viene assegnato solo agli agenti che hanno superato 50.000€ e operano nella zona Nord.
SE+O restituisce VERO se almeno una delle condizioni è soddisfatta:
=SE(O(B2="Manager";B2="Direttore");"Accesso consentito";"Accesso negato")Qui l’accesso viene concesso se il ruolo è Manager oppure Direttore.
Quando usare CERCA.VERT invece delle SE annidate
Sebbene la funzione SE annidata concatenata sia potente, esiste un punto di svolta oltre il quale conviene passare a CERCA.VERT. Quando le condizioni da gestire sono molte (più di 4-5) e corrispondono a valori presenti in una tabella, il CERCA.VERT è più leggibile, più veloce da costruire e molto più semplice da aggiornare. Per ulteriori informazioni vedi il tutorial sul CERCA.VERT.
Alternative moderne: perché usare PIÙ.SE
Con le versioni recenti di Excel (Office 365, Excel 2019 e successivi), Microsoft ha introdotto la funzione PIÙ.SE (in inglese IFS), progettata per sostituire la complessa funzione SE con più condizioni annidata.
La sintassi di PIÙ.SE è molto più lineare:
=PIÙ.SE(test1;valore1;test2;valore2;test3;valore3;…)Non è più necessario aprire e chiudere parentesi multiple. La funzione valuta i test in ordine e restituisce il valore corrispondente al primo test VERO che incontra.
Confronto:
SE Annidato: =SE(A1>90;"A";SE(A1>80;"B";"C"))
PIÙ.SE: =PIÙ.SE(A1>90;"A";A1>80;"B";VERO;"C")
Per l’ultimo argomento (il “catch-all” o else finale), in PIÙ.SE si usa spesso il trucco di inserire VERO come ultimo test, per garantire che ci sia sempre un risultato valido. Utilizzare PIÙ.SE rende i tuoi fogli di calcolo più moderni, leggibili e facili da editare.
SE.ERRORE: come gestire gli errori nelle formule
Quando una formula produce un errore (ad esempio #DIV/0!, #N/D, #VALORE!), Excel mostra quel codice di errore nella cella — il che può creare confusione nei report condivisi. La funzione SE.ERRORE ti permette di intercettare questi errori e sostituirli con un valore alternativo.
La sintassi è:
=SE.ERRORE(formula;"valore_se_errore")Esempio pratico: se vuoi dividere A1 per B1 ma B1 potrebbe essere zero o vuoto, invece di rischiare un #DIV/0! puoi scrivere:
=SE.ERRORE(A1/B1;"Divisione impossibile")Se il calcolo va a buon fine, Excel mostra il risultato; se genera un errore, mostra la scritta "Divisione impossibile". Puoi usare anche una stringa vuota ("") o uno zero (0) come valore alternativo, a seconda di come vuoi che appaia il tuo report.
Errori comuni e come risolverli
Anche gli utenti esperti possono incappare in errori utilizzando la funzione SE. Ecco i problemi più frequenti e le relative soluzioni:
Omissione del se_falso: Se scrivi =SE(A1>10;"OK") e la condizione è falsa, Excel mostrerà la scritta FALSO. Per evitarlo, specifica sempre il terzo argomento, anche se è una stringa vuota ("") o uno zero.
Dimenticare le virgolette: Scrivere =SE(A1>10;Alto;Basso) restituirà l’errore #NOME? perché Excel cerca delle funzioni o intervalli chiamati “Alto” e “Basso”. La forma corretta è "Alto" e "Basso".
Parentesi non bilanciate: Nel SE annidato Excel, ogni SE aperto deve essere chiuso. Se apri 3 parentesi, devi chiuderne 3 alla fine. Excel colora le parentesi accoppiate per aiutarti, ma l’attenzione è d’obbligo.
Numeri formattati come testo: Se il test logico fallisce inspiegabilmente (es. Excel dice che 100 non è maggiore di 50), verifica che i numeri nelle celle non siano memorizzati come testo.
Complimenti, molto chiaro. Ho ricreato gli esempi ed è andato tutto bene. Stavo però facendo alcune prove e mi sono imbattuto in un dubbio che non riesco a risolvere. Ho creato una funzione SE la quale mi restituisce dei valori numerici in base al contenuto testuale che inserisco in determinate celle. Se poi però vado a sommare ( con la semplice funzione SOMMA ) i valori numerici ottenuti con la funzione SE, mi restituisce sempre 0. Potrebbe darmni qualche suggerimento? non capisco cosa stia sbagliando. Grazie mille
Ciao Samuele,
ti ringrazio per le spiegazioni che sono sempre molto esaustive.
Ti chiedo però di darmi una mano ulteriore per risolvere un caso che ho visto non hai trattato (spero non mi sia sfuggito).
Prendiamo il caso del primo esempio che hai presentato dopo il titolo “Come si scrive la funzione SE?”. Io ho un caso simile ma devo differenziare ulteriormente il risultato se la spesa è stata fatta da una donna o se è stata fatta da un uomo. Cioè specificare che se la spesa è stata fatta da una donna deve darmi come risultato “Basso” se <100 se è stata fatta da un uomo deve darmi come risultato "Basso" se <90.
Sono un insegnante di educazione fisica è ho bisogno di valutare i miei ragazzi con parametri diversi se sono maschi o femmine. Uso la formula SE per specificare che da un dato risultato ad un altro mi deve dare valore 6, poi 7 e così via. Purtroppo però non riesco a diversificare ulteriormente in base al sesso.
Ti prego di aiutarmi.
Grazie
Toni
Ciao Toni, io penso che dovresti utilizzare due se annidati oppure una funzione E all’interno della funzione SE.
Qualcosa tipo: =SE(A2=”F”;SE(B2<100;"Basso";"Alto");SE(B2<90;"Basso";"Alto")) -> il secondo SE viene letto solo quando A2 non è F
Se cmq vuoi inviarmi uno stralcio del tuo file, senza dati sensibili ovviamente, fai pure: samuele@amicoexcel.it
Buongiorno, volevo chiedere se é possibile creare una funzione SE con riempimento cella? Esempio …se numero è uguale alla cella B2 allora colore verde…altrimenti rosso..?
Grazie
Per favore,come risolvere questo caso:
Se una cella contiene un valore superiore a 0 il risultato può essere scritto con un colore diverso dal nero?Grazie per la vostra disponibilità-
giuseppe
Ciao Giuseppe. Certo. Utilizzerei la formattazione condizionale. Prova a vedere il tutorial sulla formattazione condizionale. E se hai qualche dubbio sono qua.
Ciao Tetyana secondo me dovresti provare con la formattazione condizionale
Ciao Samuele, ho creato un menu a tendina con 3 scelte (NULLA, OPZ. 1 E OPZ. 2), molto semplicemente, vorrei fare in modo in un altra cella adiacente, di valorizzare una somma solo SE l’opzione scelta è la 1. Analogamente in un altra cella adiacente alla precedente, valorizzare una somma solo è stata scelta l’opzione 2. Non riesco a scrivere la formula…
Trovato! Dovevo inserire le Opzioni tra le virgolette!
Ottimo Moreno!
Volevo sottoporti una richiesta: dovrei utilizzare la funzione se ma ricevere più di due risposte. Esempio nubile-celibe, sposato/divorziato. Come devo impostare la formula?
Ciao Luciano, penso dovresti utilizzare il SE doppio. Questo articolo sul se annidato potrebbe esserti utile. Se vuoi farmi un esempio più dettagliato del tuo caso lo guardo volentieri.
Grazie, Samuele, ho provato con il SE annidiato ed ho impostato la formula così:
=SE(G22=1;”nubile”;SE(G22=2;”CELIBE”;SE(G22=3;”SPOSATO/DIVORZIATO”)))
funzionato alla perfezione.
Alla prossima
Ciao. Per favore potresti aiutarmi?
Ho una serie di 3500 numeri (7 cifre ciascuno) scritti tutti in colonna in A.
Li ho ordinati in modo crescente ma come faccio a sapere se ce ne sono due uguali.
Grazie mille
Raffaella
Ciao Raffaella. Per sapere se ce ne sono due uguali secondo me puoi usare almeno un paio di metodi:
1) seleziona tutte le celle, vai su formattazione condizionale, regole evidenziazione celle, valori duplicati…
Questo ti colora con un solo colore tutte le celle che hanno dei duplicati
2) sulla colonna accanto, a partire dalla seconda riga, scriverei la formula A2=A1… se restituisce VERO il numero è uguale a quello sopra
Fammi sapere. Samuele
Ciao Samuele,
con la formula SE è andato tutto benissimo.
Grazie mille
Complimenti.
Mai trovato delle lezioni così chiare e semplici ma esaustive
Grazie mille Francesca!!! 🙂
io sto facendo dei orari di lavoro e una cella la compilo con la parola chiusura alla quale li posso dare un valore tipo “IN A1 HO 18:00, “IN A2 HO CHIUSURA E IN A3 METTO LA FORMULA =SE(A2=”Chiusura”;”24:00″)-A1 e in A3 MI CALCOLA IL RISULTATO GIUSTO CHE SAREBBE 6:00 e fin qua ci siamo .se la parola CHIUSURA LA MODIFICO TIPO 23:00 COME POSSO SCRIVERE LA FORMULA…AIUTATEMI CHE STO IMPAZZENDO GRAZIE
Ciao Ermir,
potrebbe essere =SE(A2=”Chiusura”;24;A2)-A1 ?
grazie mille.
Buon pomeriggio Samuele,
il tuo blog è davvero utilissimo.
Ti chiedo una gentilezza, avrei un calcolo SE da eseguire con le seguenti caratteristiche:
La colonna H riporta una variabile in percentuale. avrei bisogno sulla casella di fianco di far si che a seconda delle seguenti regole venda riportata la dicitura 1 oppure 2 o in alternativa 3 :
0/50%=1
50/80%=2
80/100%=3
Ti ringrazio in anticipo !
Grazie!
Il tuo SE potrebbe essere =SE(H2<=50;1;SE(H2<=80;2;3)) Adattala rispetto ai valori che effettivamente hai nelle celle...non se hai il semplice rapporto (valori da 0 a 1) oppure proprio i valori percentuali
Tutto perfetto ! Era in percentuale, ma con una piccola modifica ho risolto.
Sempre gentilissimo e disponibilissimo !
Ciao Avrei una domanda al quale non riesco a trovare risposta.
Spero mi possa aiutare qualcuno
Ho una cella nel quale c’è il nome del prodotto.
All’interno del nome del prodotto ci sono svariate parole naturalmente. Faccio un paio di esempi cosi da poter essere più chiaro possibile.
riga 1 cella B1: Braccioli gonfiabili Frozen eta +3 anni
riga 2 cella B2; Giochi Preziosi – Braccioli Spiderman gonfiabili età +3 anni
Avrei bisogno di una funzione che mi permettesse di scrivere nella celle J1 “Femmina” se trova la parola Frozen e “Maschio” se trova la parola Spiderman
Stesso dicasi per la riga 2, riga 3, riga 4 ecc…..
Grazie
Buonasera Samule,
Complimenti per i tutorial, estremamente chiari e concisi, ho provato a spulciare annche i video ma non ho trovato la solouzione al mio problemino…
Ho una tabella su un foglio secondario con un elenco di province, sul principale vorrei che se in una colonna una delle province mi vinere riportata excel mi restituisca il testo A, altrimenti nulla.
Al momento la mia formula funziona solo se riporto le provincie nell’ordine esatto in cui sono scritte nella tabella sul foglio secondario, se poi provo a trascinare la formula SE nel foglio principale non funziona per nulla…
Help Me…
Roberto
Ciao Ivan.
La formula potrebbe essere:
=SE(NON(VAL.ERRORE(RICERCA(“Frozen”;B1)));”Femmina”;SE(NON(VAL.ERRORE(RICERCA(“Spiderman”;B1)));”Maschio”;””))
Due SE annidati. Il primo ha come test la verifica se c’è la parola Frozen (fatta con il RICERCA, la quale restituisce errore se non trova la stringa), nel se_falso del primo SE c’è il secondo SE.
Fammi sapere se ti può andare bene. Ciao!
Ciao Roberto. Dovresti usare il CERCA.VERT secondo me, non il SE.
Se hai dubbi mandami due dati su file Excel… samuele@amicoexcel.it
Ciao!
Caro Samuele, grazie per la tua disponibilità.
Nella cella A1 ho € 10
Nella cella A2 ho € 20
Nella cella A3 vorrei che :
– se A2 inf A1 scrivesse € 0
– se A2 maggiore di A1 scrivesse la risultante di A2-A1
Grazie 1k ed auguri di buon anno!!
Riccardo
Ciao Riccardo. Grazie, auguri anche a te.
Se hai scritto =SE(A2>A1;(A2-A1);) non vedo errori. Controlla se nelle celle A1 e A2 hai effettivamente solo 10 e 20 o c’è altro. Se vuoi mandami il file.. samuele@amicoexcel.it
Caro Samuele,
tutto risolto.
Complimenti , tutto molto utile.
Grazie 1k !
Riccardo
Buongiorno,
ma se io dovessi cercare un valore >500 e farmi restituire un testo e invece dove il valore non è >500 lasciare il valore che c’è è fattibile?
Grazie
Valeria
Buonasera Valeria,
il tuo SE potrebbe essere qualcosa tipo =SE(A2>500;”tuo_testo”;A2).
Se il valore non è maggiore di 500 allora riscrivi il valore stesso.
Buongiorno,
avrei bisogno di ottenere questo risultato : se il valore di una cella (es. D4) è pari a 0,00 sostituiscilo con il valore della cella soprastante (es. D3). Come posso fare?
Grazie mille
Rossana
Buongiorno Rossana, in un’altra cella scriverei =SE(D4=0;D3;D4). Può essere?
Buongiorno,
non riesco a capire come inserire una formula…le spiego.
ES:
cella A1 scritta ALTO, cella B1 scritta ALTO, vorrei che nella cella C1 uscisse una scritta tipo DA VENDERE
mentre
se nelle celle A e B ci fosse scritto BASSO la C1 dicesse DA SCARTARE
e nel caso di ALTO BASSO, C1 dicesse DA CONTROLLARE
spero di essermi spiegato
Non so se quello che sto chiedendo è oggetto di ciò che state discutendo in questa pagina ma mi farebbe un favore enorme se mi potesse aiutare
Grazie infinite
Ciao Alessandro.
Vedo due strade:
1) SE annidati con all’interno la E
=SE(E(A1=”alto”;B1=”alto”);”da vendere”;SE(E(A1=”basso”;B1=”basso”);”da scartare”;”da controllare”))
2) un CERCA.VERT
costruendo una matrice tabella, ad esempio in I1:J4, fatta così
altobasso da controllare
bassoalto da controllare
bassobasso da scartare
altoalto da vendere
la funzione potrebbe essere
=CERCA.VERT(A1&B1;I$1:J$4;2;0)
Fammi sapere. Ciao!
Ciao Samuele,
scusa se disturbo ma avrei necessita di fare un’operazione complessa su excel.
In una cella (M83) ho scritto una funzione tipo =SE(G83<=14,5;"0";SE(G83<=24,5;"100";SE(G83=34,5;”550″))))….bene funziona! Fin qui tutto semplice (immagino avrei potuto scrivere una formula più semplice…ma…non importa).
Tuttavia il mio quesito non è terminato. Devo fare un altro controllo, cioè:
se il valore della cella della stessa riga (F83) è > del risultato della formula scritta in M83 di cui sopra allora scrivi il contenuto di F83 altrimenti lascia il risultato ottenuto dalla formula .
Aiuto!!! 😮
Non è che mi aiuteresti. Grazie100000
Buongiorno Samuele
complimenti per i tutorial.
La mia domanda è la seguente:
supponiamo di avere in A1 un valore prefissato, in A2 un valore che cresce progressivamente. È possibile, nel momento in cui A2 diventa = o > di A1, saltare alla cella sucessiva A3 e proseguire il conteggio ?
Grazie e buona giornata.
Marco.
Ciao!
Aggiungerei un SE davanti…
La tua originale è
=SE(G83<=14,5;"0";SE(G83<=24,5;"100";SE(G83=34,5;”550″)))) potresti aggiungere =SE(F83>(SE(G83<=14,5;0;SE(G83<=24,5;100;SE(G83=34,5;550))));F83;SE(G83<=14,5;0;SE(G83<=24,5;100;SE(G83=34,5;550)))) però occhio alle virgolette sui numeri.. toglile se vuoi risultati numerici, altrimenti saranno testuali
Grazie tanto,da 4 lezioni non ho capito il commando ma grazie a te l’ho capito subito.Ti stimo tanto.
Grazie Matteo! 🙂
buongiorno, ti ringrazio per gli esempi che ho cercato di comprendere, ma fino ad ora non sono ancora riuscito a fare quello che mi serviva a me; provo a spiegarti
ho in una cella un valore (risultato di una somma fra diverse celle) che può teoricamente andare da 5 a 600 ed il valore entro il quale lo vorrei far visualizzare non deve superare il120
ho provato a fare questo =SE(M1>600;SE(M1>480;SE(M1>360;SE(M1<240;SE(M1<120);M1-120;M1)
per riportare il valore entro il 120 e non superiore, ma mi da errore.
Grazie per la spiegazione che riuscirai a darmi.
buona giornata
UGO
Buongiorno Ugo. Non mi è chiaro perché nella formula vai a valutare 480, 360, 240 ecc. Forse manca qualche info su questo.
Con =SE(M1>120;M1-(M1-120);M1) faresti vedere il numero se inferiore a 120 o lo imposteresti a 120 se superiore
Buon giorno Samuele
Chiedo il tuo aiuto in quanto non riesco a scrivere una formula.
Ho necessità di riempire una cella in base al riempimento di un’altra. Ad esempio:
Se nella cella A1 viene inserita una A, nella cella B1 deve comparire automaticamente 10.
Se nella cella A1 viene inserita una B, nella cella B1 deve comparire automaticamente 9.
Se nella cella A1 viene inserita una C, nella cella B1 deve comparire automaticamente 8.. e così via.
Per ora ho scritto solo questo pezzo: =SE((C2=”A+”);”10″) ma non riesco ad andare avanti.
Spero possa aiutarmi.
Ti ringrazio in anticipo.
Nicola
Ciao Nicola.
Alcune soluzioni che mi vengono in mente:
1) funzione SE annidata
=SE(A1=”A”;10;SE(A1=”B”;9;SE(A1=”C”;8;7)))
al posto del 7 inserisci un altro SE con la stessa logica dei primi… e via via fino a prendere in considerazione tutti i valori
2) se hai una versione di Excel che ha la funzione PIÙ.SE
=PIÙ.SE(A1=”A”;10;A1=”B”;9)
aggiungendo dopo il 9 tutte le altre condizioni
3) sfruttando la funzione CODICE, che restituisce il codice in base al set di caratteri installato
=10+65-CODICE(A1)
4) creando una tabellina con con lettere nella prima colonna e numeri nella seconda,
un CERCA.VERT
Fammi sapere. Ciao!
Buonasera ,
Grazie per gli esempi esposti , volevo chiederle un aiuto in merito ad una funzione che non riesco a trovare.
in una casella vorrei scrivere un valore numerico es da 1 a 10 e far colorare la casella adiacente di un colore corrispondente , 10 colori diversi a mia scelta che cambieranno a secondo il valore numerico posto nella casella numerica.
Grazie anticipatamente e buona serata
Ciao Gianpaolo, dovresti provare con la formattazione condizionale, strumento che colora a seconda del contenuto.
Buonasera,
volevo chiederle un aiuto, sto svolgendo un problema dove mi chiede:
Se l’ultima lettera del nome è “a” scrivere “donna”, altrimenti “uomo” (utilizzare la funzione Destra per trovare l’ultima lettera)
come devo impostare la formula?
Grazie in anticipo
Buonasera Antonella,
=SE(DESTRA(a2)=”a”;”donna”;”uomo”)
Nel caso di presenza di spazi:
=SE(DESTRA(ANNULLA.SPAZI(a2))=”a”;”donna”;”uomo”)
Chiarissimo grazie mille.
Ora mi trovo nella casella successiva dove praticamente devo svolgere questo: se è “idoneo/a” e “uomo” scrivi “attore”, altrimenti “respinto”. Se è “idoneo/a” e “donna” scrivi “attrice” , altrimenti ” respinta” (usare SE come funzione principale e al suo interno). Ho provato così:
=SE(E(K2=”idoneo/a”;L2=”uomo”);”attore”;”respinto”);SE(E(K2=”idoneo/a”;L2=”donna”);”attrice”;”respinta”)
ma mi esce errore
Ciao Samuele, ho bisogno di un aiuto. Devo inserire una funzione in un contesto di questo tipo: se nella casella A1 è inserita la lettera A restituiscimi il valore 1, se la lettera B, il valore 2, se la lettera C il valore 3 ecc… Quale funzione devo utilizzare? Ho provato con la funzione =SE, ma non mi funziona su più di una lettera. Illuminami… 🙂 Grazie mille
Ciao Andrea. Utilizzerei il CERCA.VERT.
Puoi costruirti una tabella su cui cercare, formata da due colonne.
Nella prima scrivi A, B, C, ecc. Nell’altra 1, 2, 3.
Ciao Complimenti per il sito
Avrei la necessità di cambiare il colore di riempimento di una cella nel caso la cella contenga due testi specifici per esempio : “Dom” o “Sab” sono riuscito utilizzando la formattazione condizionale, ma funziona solo per un testo non riesco a fare OR dei due.
Grazie in anticipo
Salve avrei bisogno di un aiuto:
ho impostato una cella a tendina con 5 giudizi, pieno e consapevole, pieno, buono, parziale, scarso;
vorrei impostare in una cella una formula in cui se nella la cella a tendina fosse selezionata pieno e consapevole vorrei che mi comparisse il numero 5, se pieno il numero 4, se buono il numero 3, ect.. come posso fare? ho provato con il se ma non riesco
grazie anticipatamente
Salve Rita. Farei così:
=SE(A2=”pieno e consapevole”;5;SE(A2=”pieno”;4;SE( ecc. ecc. )))
oppure
=PIU’.SE(A2=”pieno e consapevole”;5;A2=”pieno”;4;ecc.
Buongiorno Samuele, un aiuto cortesemente:
Utilizzando la funzione Se considerando una tavella avente 2 colonne,sulla prima A 5 righe aventi nomi, sulla seconda B, in corrispondenza del nome un valore.
La formula deve restituire il nome riferito a chi ha il voto più alto. Es.: Mario
Grazie
Buongiorno Walter,
con la funzione MAX ci si potrebbe trovare il valore più alto. Con le funzioni INDICE e CONFRONTA ci si potrebbe trovare il nome. Tipo:
=INDICE(A2:A10;CONFRONTA(MAX(B2:B10);B2:B10;0))
Buongiorno Samuele,
ho un piano di ammortamento di un mutuo, con una colonna riferita alle scadenze delle rate ed una riferita al capitale residuo dopo il pagamento della rata corrispondente. Ho bisogno di una formula che prenda dalla colonna il valore del capitale residuo alla data odierna in automatico. Grazie.Complimenti per il sito.
Alla fine ci sono arrivato così VLOOKUP(TODAY();intervallo intera tabella;colonna capitale residuo)
Ottimo Francesco. E grazie per il gentile feedback.
Complimenti Samuele per la tua competenza.
Volevo chiederti un aiuto.
Ecco il mio problema: vorrei capire se esiste una funzione “logica” che ti permette di “inserire” in automatico un valore in una cella di excel se sono presenti CONTEMPORANEAMENTE determinati “valori” in altre DUE celle.
In altre parole se nella cella “A” è presente il valore “x” e nella cella “B” è presente CONTEMPORANEAMENTE il valore “y”, allora nella cella “C” excel inserirà in automatico il numero “z”.
Nello specifico io vorrei ottenere questo:
cella in Colonna A: può assumere due valori H o L.
cella in Colonna B: può assumere due valori H o L.
cella Colonna C: voglio che mi dia in “automatico” uno dei seguenti numeri in base alle possibili combinazioni delle colonne A e B, ossia:
Col A. e Col.B …Col. C
H e H …. 1
H e L …. 2
L e H …. 3
L e L …. 4
Ho letto la sintassi della regola “SE” ma non mi sembra faccia al caso mio. O mi sbaglio?
Grazie mille in anticipo per la tua disponibilità.
Anna
Ciao Anna.
Puoi usare la funzione E nel test del SE.
Quindi =SE(E(A2=”H”;B2=”H); 1;SE(E(A2=”H”;B2=”L);2;SE(ecc.)
Qui trovi il mio tutorial:
https://www.amicoexcel.it/funzione-e/
Oppure, come alternative, puoi dare un’occhiata alle funzioni PIU’.SE o CERCA.X
Buongiorno.
Sto provando in tutti i modi a scrivere una formula SE che mi aiuti in questo:
Colonna A -> dei termini in italiano
Colonna B -> in B1 vorrei scrivere FRA (per francese) o ENG (per inglese)
La funzione SE dovrebbe essere: SE in B1 c’è FRA, restituisci (parola in francese), altrimenti (parola in inglese).
Poi a seconda della traduzione che mi serve (se inglese o francese), in B1 andrò a scrivere FRA o altro.
È corretta impostata come segue?
A1: vuoto
A2: comincia l’elenco delle parole in italiano
B1: FRA (o altro)
B2: =SE(B1=fra;chassis;undercarriage)
Che sarebbe: se in B1 c’è FRA, restituiscimi chassis, altrimenti undercarriage.
Vi prego, aiutatemi!
Ciao Marta. Sì corretto. Aggiungici solo i doppi apici, perché sono criteri testuali:
=SE(B1=”fra”;”chassis”;”undercarriage”)
Curiosità: perché non valuti la creazione di un elenco con termini italiano e accanto francese, poi un elenco con tenrmini italiano e accanto inglese.?
Poi con un CERCA.VERT in B2: =CERCA.VERT(A2;se(b1=”fra”;D:E;G:H);2;0) Dove D:E è l’intervallo dove costruisci il primo elenco italiano francese…G:H italiano inglese.
Non voglio cmq complicarti la vita… è che in generale mi sembrerebbe un modo di lavorare più elastico… anche se poi va calato nel tuo contesto.
Buonasera.
Ho due colonne: in una dei nomi che si possono anche ripetere e nell’altra un prodotto che può cambiare.
Excel è in grado di evidenziarmi quei nomi che sono associati ad un cambio di prodotto nella colonna B?
In pratica, mi serve capire se Excel riesce a filtrare solo quei nomi presenti nella colonna A associati ad una variazione di prodotto nella colonna B.
Se Giuseppe (colonna A) è sempre associato alla mela (colonna B), non mi interessa; mi interessa Giuseppe se prende una volta la mela, una volta la pera, ecc.
Ciao Samuele,
necessitavo di filtrare nomi maschili e femminili per impostare una lettera con dato variabile “Egr. Sig.” o “Gent.le Sig.ra”. Ho trovato la formula spiegata chiaramente!!!! A differenza di altri siti visitati prima: troppo complicati nelle spiegazioni
MI sono imbattuta casualmente su questo sito, e ci tornerò sicuramente ogni volta che ne avrò necessità.
Mille grazie e i miei più calorosi complimenti.
Tatiana
Tatiana grazie mille. Il tuo commento mi rende davvero molto felice 🙂
Buongiorno, ho creato una funzione PIU.SE ma non riesco a copiarla correttamente sul resto delle celle .Quale suggerimento mi da ?
Grazie
Se non hai già risolto… giramela… samuele@amicoexcel.it
Salve, cercavo una formula semplice per potermi calcolare le ore lavoro in base ai turni e riposi Malattie e ferie, ma non riesco con la formula.
Vorrei fare una cella che se metto sulla cella A1 il num. 1 (primo turno), sulla cella A2 mi appare 8 (che sarebbero ore) sempre nella stessa cella A1 se metto il num. 2 sulla cella A2 mi appare 8, se metto 3 appare 7,5 (sempre ore), però se metto sulla cella A1 R (riposo) sulla cella A2 appare 0, se su A1 metto F sulla cella A2 apre scritto ferie e se metto M appare Malattia e così via.
Praticamente sulla stessa cella in base a ciò che inserisco sulla cella a fianco mi appaia la formula.
Spero sono stato chiaro e ringrazio anticipatamente chi mi sa dire la formula come farlo.
Ciao Salvatore. Dovresti usare la funzione PIU’.SE oppure usare dei se annidati. Rispetto a questa secondo metodo trovi info sulla pagina dedicata al SE doppio.
Nella cella A2 sarà qualcosa tipo =SE(A1=1;8;SE(A2=2;8;SE(A2=3;7,5; ecc.
Ciao Samuele, molto chiaro nelle spiegazioni. Non trovo però la soluzione al mio problema.
Ho due tabelle, nella prima, indico con il codice ROL il valore 1, ROL2 il valore 2,ROL3 il valore 3, così via fino a ROL8 il valore 8; i valori si vanno a sommare in una determinata casella di una seconda tabella. I codici vanno elencati i una colonna di max 31 celle.
Ho usato la formula =CONTA.SE(E3:E33;”ROL”) ma così individuo solo la scritta rol ma non tutto il resto.
Ho usato la formula =SE(E3=”rol2″;2;0)+SE(E4=”rol2″;2;0)+SE(E5=”rol2″;2;0)+SE(E6=”rol2″;2;0)+SE(E7=”rol2″;2;0)+SE(E8=”rol2″;2;0)+SE(E8=”rol2″;2;0)+SE(E10=”rol2″;2;0)+SE(E11=”rol2″;2;0)+SE(E12=”rol2″;2;0)+SE(E13=”rol2″;2;0)+SE(E14=”rol2″;2;0)+SE(E15=”rol2″;2;0)+SE(E16=”rol2″;2;0)+SE(E17=”rol2″;2;0)+SE(E18=”rol2″;2;0)+SE(E19=”rol2″;2;0)+SE(E20=”rol2″;2;0)+SE(E21=”rol2″;2;0)+SE(E22=”rol2″;2;0)+SE(E23=”rol2″;2;0)+SE(E24=”rol2″;2;0)+SE(E25=”rol2″;2;0)+SE(E26=”rol2″;2;0)+SE(E27=”rol2″;2;0)+SE(E28=”rol2″;2;0)+SE(E29=”rol2″;2;0)+SE(E30=”rol2″;2;0)+SE(E31=”rol2″;2;0)+SE(E32=”rol2″;2;0)+SE(E33=”rol2″;2;0) ma così individuo solo ROL2 (o ROL3 e così via. Ma non mi permette di sommare i vari valori un una casella. (lo posso ottenere facendo la somma di tutti i risultati ottenuti)
Esiste un metodo “più veloce” per avere la somma dei miei ROL?
Grazie della tua disponibilità.
Ciao Antonio.
Io vedo queste due soluzioni. Una un po’ “grezza”, basata su CONTA.SE, ed una più elegante, basata su forme matriciali.
Prima soluzione:
=CONTA.SE(E3:E33;”rol”)+2*CONTA.SE(E3:E33;”rol2″)+3*CONTA.SE(E3:E33;”rol3″)+ ecc..
Seconda soluzione:
Perché funzioni dovresti scrivere ROL1 al posto di ROL
=SOMMA(–DESTRA(E3:E13;1)) in forma matriciale… vuol dire che non devi confermare con INVIO ma con CTRL+SHIFT+INVIO
Ciao!
Salve,
Intanto grazie perché questo sito è uno strumento che uso spesso e mi aiuta tanto nel lavoro;
avrei gentilmente bisogno di un ‘indicazione.
Ho un file con un elenco di abbonamenti ed una colonna con la data di scadenza di ognuno.
Vorrei creare una colonna dove per ogni abbonamento sia indicato se , rispetto alla data dell’aggiornamento settimanale, l’abbonamento é :A.scaduto B.a scadere tra 3 /12 mesi C. non scaduto D.a scadere entro 3 mesi
Spero di essere stata abbastanza chiara..ho provato con la formattazione condiz ma dava risultati contrastanti e con la diff tra date compariva Valore..
Grazie in anticipo per l’aiuto che mi potra fornire.
Un saluto
S.
Buon giorno, vorrei sapere se la formula SE funziona solo con i numeri o anche con le parole. Ho provato ad inserire la formula guidata con SE e nella casella del test ho inserito una cella che fa riferimento a un nome e mi segna errore perché non è un valore. Ora ti spiego qual è il mio problema. Nel file del bilancio famigliare ho due colonne dove devo inserire i dati che le vorrei rendere più agili. Nella colonna A ci sono celle con tendina a discesa con 4 voci, “casa, auto, personali, ecc..”. Ogni voce ha delle sotto voci. Nella colonna B ci sono le celle a discesa con tutte le sotto voci che sono tante. Volevo sapere se è possibile nelle cella della colonna B richiamare l’elenco della voce che ho definito nella cella della colonna A? Esempio SE A1 = casa inserisci l’elenco riferito a casa che avrò messo nella colonna M1:M6. Non so sono riuscito a spiegare cosa vorrei fare. Ringrazio per la tua disponibilità.
Ciao Stefania. Grazie a te, mi fa molto piacere che il blog ti sia d’aiuto.
Per la tua necessità va bene la formattazione condizionale se vuoi colorare. Oppure la funzione SE se vuoi scrivere “scaduto”, “scadere tra..” ecc.
Le regole da creare, sia nella formattazione che nel SE, possono sfruttare la funzione OGGI()… quindi, ad esempio, SE(data<=OGGI();"scaduto".... oppure SE(data>OGGI();”non scaduto”…. SE(E(data>OGGI();data<=OGGI()+90);"a scadere entro 3 mesi... Se poi hai problemi mandami le formule in un file a samuele@amicoexcel.it
Ciao Giacomo. La funzione SE funziona anche con il testo, con l’accortezza di aggiungere gli apici.. esempio: SE(A2=”tuo_testo”).
Quel che mi descrivi in realtà mi fa pensare a delle tendine collegate tra loro… Prova a vedere il mio articolo dedicato alla tematica dei menu a tendina collegati
Grazie mille per la rapidità della risposta. Ho letto il tuo articolo sull’argomento ed è stato molto interessante. Non conoscevo assolutamente la funzione “indiretto”. mentre la funzione convalida dati la usavo solo per creare il menu a tendina senza saper per altre funzioni. Per curiosità, anche con la formula SE è possibile fare il menu a tendina collegati, anche se più complicato? Ancora grazie mille. Saluti
Buongiorno,
vorrei sapere se e’ possibile utilizzare la funzione se con il colore di una cella. mi spiego meglio.
Nel momento in cui verra’ colorata di verde una cella della colonna A nella cella della colonna B il numero 1 deve diventare 0.
Grazie anticipatamente
Figurati Giacomo. Non mi pare sia possibile creare il menu a tendina con i SE.
Possibile scrivendo del codice VBA. La funzione SE non è in grado di verificare la formattazione di una cella.
Grazie mille per la tua risposta.. e’ possibile avere un esmpio?
grazie ancora
Ciao Samuele e grazie
io vorrei utlizzare il SE e ALLORA
mi spiego meglio :
se (una cifra uguale a zero) allora inserisci altra cifra (di un’altra casella)
se non uguale a zero inserisci quella (cifra), spero di essermi spiegato , come fare?
Buongiorno Samuele,
ho una tabella con nome cliente, tipo appuntamento ,data ,ora.
Vorrei che questa tabella compilasse in automatico un’agenda settimanale.
Sai darmi qualche dritta?
Grazie.
Buongiorno Marco.
Secondo me dovresti utilizzare VBA. Dopo aver inserito una riga con un pulsante dovresti scrivere il dato all’interno della tua agenda. Non banale se non conosci VBA.
Buongiorno,
ho una lista di oggetti nelle celle e se il valore della cella e maggiore di 0 deve ricopiare la cella.(=SE(F11>=1;A11;””))
A questo punto se la cella contiene il testo che ho copiato deve inserirla in un altra cella in ordine .
Il problema è che ci possono essere delle celle vuote sapete indicarmi la funzione da scrivere
grazie
Salve Massimo.
Ok la prima parte.
La seconda non mi è chiara:
“A questo punto se la cella contiene il testo che ho copiato deve inserirla in un altra cella in ordine .”
Buon giorno Samuele,
ho letto le tue risposte ai vari interrogativi che ti fanno e le ho trovate chiare. Vorrei chiederTi se con la formula SOMMA.SE si possono inserire valori negativi. Mi spiego meglio, la formula che ho inserito funziona bene se inserisco valori positivi, quando inserisco un valore negativo, mettendo il meno davanti al numero toglie un valore doppio di quello che inserito. Bisogna modificare la formula per fare accettare valori negativi? La formula è questa: =SOMMA.SE($F$8:$F$498;”R”;$D$8:$D$498) dove F è la colonna della condizione e D la colonna dei valori. Ti ringrazio per la tua disponibilità.
Non mi risulta Giacomo. Vuoi mandarmi le due colonne e la formula così verifico? samuele@amicoexcel.it
Molto utile il tutorial, vorrei chiederti un aiuto. Mi servirebbe capire come poter scrive la funzione se per fare un’operazione un pò complessa. In una colonna C ho un testo e può esserci scritto “x” o “y” o “z”. Se in quelle 30 righe c’è scritto “x” allora mi serve la media dei punteggi (che ho in una colonna “e”) però gli altri punteggi, rispettivamente delle Y e delle Z non devono essere inclusi nella media.
Esempio
C … … …. E
x 1
x 3
y 6
y 5
z 3
x 8
vorrei costruire una tabella a parte per fare la media di tutte le X, le Y e le Z. Per esempio vorrei che mi facesse la media dei punteggi in colonna “E” se nella colonna C c’è scritto X (quindi in questo caso la media di 1 3 e 8), ma non prendere i punteggi della colonna E se nella colonna C c’è scritto Y o Z. E così via anche con le “Y” e delle “Z”.
Ciao Evelina,
potresti usare la funzione MEDIA.SE…
=MEDIA.SE(C:C;”x”;E:E)
Calcola la media della colonna E ma solo per i valori che nella colonna C sono uguali a “x”.
Al posto di “x” nella formula puoi ovviamente far riferimento ad una cella dove hai scritto x, y oppure z:
=MEDIA.SE(C:C;G2;E:E)
Qui trovi la guida ufficiale sulla funzione MEDIA.SE di Excel:
https://support.microsoft.com/it-it/office/media-se-funzione-media-se-faec8e2e-0dec-4308-af69-f5576d8ac642
Buongiorno ho un problema con la funzione logica “SE”: cella E1 Deve restituire il valore delle uscite future cioè C8-E8. Ma se la cella E5 si mette il Valore “0” (zero a numero, quindi è una spesa che non avverra o sara parziale) il corrispondente valore della C5 andra a sottrarre il valore intero della E1 ovvero andra a sottrarre la differenze tra C5 e E5. Lo stesso criterio si dovra applicare alla cella E1 per le righe 6 e 7 colonne C ed E.
————————————————————————–
A B C D E
—————————————————————————-
1- s.do iniz : 5300 usciranno : 300
nel mese
2- saldo attuale: 5300 restano disponibili ?????
——————————————————————————
3- da pagare pagato
——————————————————————————-
5 100 casa
6 100 utenze
7 100 altro
————————————————————————–
8 totale 300 ???
———————————————————————-
A B C D E
————————————————————————–
In attesa di Sua cortese attenzione la ringrazio in anticipo.
Buongiorno Giancarlo.
Volentieri la aiuto se posso. Ma sarebbe meglio che io vedessi i dati su file. Me lo invii se vuole a samuele@amicoexcel.it.