La funzione SE ci permette di valutare il contenuto di una cella e di prendere di conseguenza una decisione.

Se la cella con la quantità a magazzino è minore o uguale a 1000 voglio scrivere “Prodotto da riordinare” altrimenti scrivo “Scorta sufficiente”.

funzione se

La funzione SE è quindi concettualmente per noi tutti molto intuitiva. Applica infatti un ragionamento che facciamo 100 volte al giorno. Valutiamo una situazione e di conseguenza facciamo una scelta:

Se c’è il sole utilizzo la bici altrimenti prendo la macchina. Se leggo fino in fondo questo breve tutorial imparo bene la funzione SE altrimenti no. 🙂

Come si scrive la funzione SE?

La funzione SE va scritta in una singola cella. Spesso poi la cella è la prima di un elenco quindi essa viene trascinata verso il basso su tutte le righe dell’elenco.

Ecco come va scritta la funzione SE:

=SE(E2<=100;”Basso”;”Alto”)

funzone se sintassi

La funzione SE richiede tre parametri:

– il Test (obbligatorio): è una espressione che chiediamo ad Excel di valutare, in questo caso chiediamo se il valore della cella E2 è minore o uguale a 100

– il Se_vero (facoltativo): quel che vogliamo far fare a Excel quando il test è vero. Nell’esempio vogliamo scrivere “Basso” ma, come vedremo negli altri esempi di questo tutorial, a volte potremmo voler far eseguire un calcolo invece che far scrivere un testo/numero/data

– il Se_falso (facoltativo): su questo parametro excel “arriva” quanto il test è falso, nel nostro caso quanto è falso che E2 è minore o uguale a 100, quindi quando E2 è maggiore di 100. Per questo facciamo scrivere “Alto”

Questo il risultato finale:

risultato finale funione logica se

Quando Se_vero o Se_falso non vengono specificati il risultato sarà uno dei due valori logici VERO o FALSO.

Se preferiamo inserire il SE utilizzando la finestra di inserimento dei parametri questi sono i passaggi:

 1  ci si posiziona sulla cella dove si vuole il risultato

finestra funzioni logiche

 2  si clicca sul tastino Fx di inserimento funzioni e nella tipologia Logiche si sceglie il SE

 3  si definiscono il test e i parametri Se_vero e Se_falso

finestra funzione se

Il SE appartiene alle funzioni logiche ed è tra le più utilizzate tra tutte le funzioni. Si presta, infatti, a risolvere tantissime situazioni che richiedo una verifica di una situazione.

Casi pratici funzione SE

Ecco alcune casi pratici di utilizzo della funzione SE.

Esempio 1. Vogliamo scrivere “Donna” quando la cella del genere riporta “F”, “Uomo” altrimenti.

=SE(B2=”f”;”Donna”;”Uomo”)

esempio pratico funzione se uguale a

che potrebbe anche essere scritta in questo modo:

=SE(B2<>”f”;”Uomo”;”Donna”)
dove <>”f” significa diverso da “f”

esempio pratico funzione se diverso da

Esempio 2. Vogliamo calcolare un importo scontato applicando uno sconto del 5% se il cliente ha speso meno di 100 euro, del 10% se ha speso da 100 in su.

=SE(B2<100;B2*0,95;B2*0,9)

caso pratico se sconto

Esempio 3. Vogliamo nascondere temporaneamente il risultato di una formula. Nell’esempio qui sotto viene calcolata la somma cumulata degli importi aggiungendo il valore del singolo mese alla somma dei mesi precedenti.

La formula se senza restituisce un valore fuorviante:

caso pratico formula da nascondere

Possiamo aggiustare inserendo un SE per far sapere ad Excel che vogliamo che visualizzi la somma cumulata solo per i mesi per cui abbiamo già il valore dell’importo:

=SE(B3<>””;B3+C2;””)

caso pratico formula nascosta con se

Esempio 4. Vogliamo verificare la correttezza dei codici prodotto. Se la lunghezza del codice è pari a 9 il codice ha un numero esatto di cifre altrimenti segnaliamo che il codice è errato.

=SE(LUNGHEZZA(B2)=9;”ok”;”codice errato”)

esempio pratico funzione lunghezza

Esempio 5. Se le ultime lettere del codice prodotto sono “FFF” allora noi sappiamo che il prodotto è una sedia, altrimenti è un tavolo.

esempio pratico funzione destra testuale

=SE(DESTRA(B2;3)=”fff”;”sedia”;”tavolo”)

Attenzione però che se avessimo un codice con tre numeri finali dovremmo ricordare comunque che la funzione DESTRA restituisce un risultato testuale. Quindi andrebbe scritta in questo modo:

=SE(DESTRA(B2;2)=”40″;”sedia”;”tavolo”)

oppure in questo modo:

=SE(- -DESTRA(B2;2)=40;”sedia”;”tavolo”)
dove il – – davanti alla funzione DESTRA converte il risultato di destra in numerico

esempio pratico funzione destra trasformata in numero

Il modo errato sarebbe: =SE(DESTRA(B2;2)=40;”sedia”;”tavolo”)

esempio pratico funzione destra non trasformata errato

Esempio 6. La funzione SE può essere utilizzata anche in combinata con il cerca verticale. E in più modi:

– per richiamare un cerca vert piuttosto che un altro
=SE(B2<100;CERCA.VERT(B2;K1:N500;2;0);CERCA.VERT(B2;P1:S500;3;0))

– per modificare in maniera dinamica il riferimento alla matrice tabella
=CERCA.VERT(B2;SE(B2<100;K1:N500;P1:S500);2;0)

SCOPRI IL MIO NUOVO VIDEO CORSO SU CERCA.VERT. Diventa un esperto sul cerca verticale con esempi pratici e 21 ESERCIZI CON VIDEO SOLUZIONI!

corso cerca vert esempi pratici

Funzione SE con date

Quando utilizziamo nella funzione se una data, può capitare di trovarci di fronte ad una data memorizzata come testo, cosa che può succedere ad esempio quando il file è una estrapolazione da un database. In questo caso dobbiamo convertire la data testuale attraverso la funzione DATA.VALORE, la quale converte una data in formato testo in un numero quindi una data, come ci dice anche la guida ufficiale.

=SE(B2<DATA.VALORE(“1/1/2016”);”Pre 2016″;”2016 o successivo”)

funzione se data

Se la data è in formato numerico/data possiamo invece scrivere: =SE(B2<1/1/2016;”Pre 2016″;”2016 o successivo”)

Chiaramente potremmo fare riferimento senza problemi ad una data scritta in una cella esterna:

=SE(B2<G$1;”Pre 2016″;”2016 o successivo”)

funzione se data con cella esterna

Se hai trovato interessante questo tutorial sulla funzione SE forse ti può interessare anche il tutorial sui SE ANNIDATI 🙂

tutorial se annidati

Guida funzioni (pdf)

95 Comments

  1. Complimenti, molto chiaro. Ho ricreato gli esempi ed è andato tutto bene. Stavo però facendo alcune prove e mi sono imbattuto in un dubbio che non riesco a risolvere. Ho creato una funzione SE la quale mi restituisce dei valori numerici in base al contenuto testuale che inserisco in determinate celle. Se poi però vado a sommare ( con la semplice funzione SOMMA ) i valori numerici ottenuti con la funzione SE, mi restituisce sempre 0. Potrebbe darmni qualche suggerimento? non capisco cosa stia sbagliando. Grazie mille

  2. Ciao Samuele,
    ti ringrazio per le spiegazioni che sono sempre molto esaustive.
    Ti chiedo però di darmi una mano ulteriore per risolvere un caso che ho visto non hai trattato (spero non mi sia sfuggito).
    Prendiamo il caso del primo esempio che hai presentato dopo il titolo “Come si scrive la funzione SE?”. Io ho un caso simile ma devo differenziare ulteriormente il risultato se la spesa è stata fatta da una donna o se è stata fatta da un uomo. Cioè specificare che se la spesa è stata fatta da una donna deve darmi come risultato “Basso” se <100 se è stata fatta da un uomo deve darmi come risultato "Basso" se <90.
    Sono un insegnante di educazione fisica è ho bisogno di valutare i miei ragazzi con parametri diversi se sono maschi o femmine. Uso la formula SE per specificare che da un dato risultato ad un altro mi deve dare valore 6, poi 7 e così via. Purtroppo però non riesco a diversificare ulteriormente in base al sesso.
    Ti prego di aiutarmi.
    Grazie
    Toni

  3. Ciao Toni, io penso che dovresti utilizzare due se annidati oppure una funzione E all’interno della funzione SE.

    Qualcosa tipo: =SE(A2=”F”;SE(B2<100;"Basso";"Alto");SE(B2<90;"Basso";"Alto")) -> il secondo SE viene letto solo quando A2 non è F

    Se cmq vuoi inviarmi uno stralcio del tuo file, senza dati sensibili ovviamente, fai pure: samuele@amicoexcel.it

  4. Buongiorno, volevo chiedere se é possibile creare una funzione SE con riempimento cella? Esempio …se numero è uguale alla cella B2 allora colore verde…altrimenti rosso..?
    Grazie

  5. Per favore,come risolvere questo caso:
    Se una cella contiene un valore superiore a 0 il risultato può essere scritto con un colore diverso dal nero?Grazie per la vostra disponibilità-
    giuseppe

  6. Ciao Samuele, ho creato un menu a tendina con 3 scelte (NULLA, OPZ. 1 E OPZ. 2), molto semplicemente, vorrei fare in modo in un altra cella adiacente, di valorizzare una somma solo SE l’opzione scelta è la 1. Analogamente in un altra cella adiacente alla precedente, valorizzare una somma solo è stata scelta l’opzione 2. Non riesco a scrivere la formula…

  7. Volevo sottoporti una richiesta: dovrei utilizzare la funzione se ma ricevere più di due risposte. Esempio nubile-celibe, sposato/divorziato. Come devo impostare la formula?

  8. Grazie, Samuele, ho provato con il SE annidiato ed ho impostato la formula così:
    =SE(G22=1;”nubile”;SE(G22=2;”CELIBE”;SE(G22=3;”SPOSATO/DIVORZIATO”)))
    funzionato alla perfezione.
    Alla prossima

  9. Ciao. Per favore potresti aiutarmi?
    Ho una serie di 3500 numeri (7 cifre ciascuno) scritti tutti in colonna in A.
    Li ho ordinati in modo crescente ma come faccio a sapere se ce ne sono due uguali.
    Grazie mille
    Raffaella

  10. Ciao Raffaella. Per sapere se ce ne sono due uguali secondo me puoi usare almeno un paio di metodi:

    1) seleziona tutte le celle, vai su formattazione condizionale, regole evidenziazione celle, valori duplicati…
    Questo ti colora con un solo colore tutte le celle che hanno dei duplicati

    2) sulla colonna accanto, a partire dalla seconda riga, scriverei la formula A2=A1… se restituisce VERO il numero è uguale a quello sopra

    Fammi sapere. Samuele

  11. Ciao Samuele,
    con la formula SE è andato tutto benissimo.
    Grazie mille

  12. Complimenti.
    Mai trovato delle lezioni così chiare e semplici ma esaustive

  13. io sto facendo dei orari di lavoro e una cella la compilo con la parola chiusura alla quale li posso dare un valore tipo “IN A1 HO 18:00, “IN A2 HO CHIUSURA E IN A3 METTO LA FORMULA =SE(A2=”Chiusura”;”24:00″)-A1 e in A3 MI CALCOLA IL RISULTATO GIUSTO CHE SAREBBE 6:00 e fin qua ci siamo .se la parola CHIUSURA LA MODIFICO TIPO 23:00 COME POSSO SCRIVERE LA FORMULA…AIUTATEMI CHE STO IMPAZZENDO GRAZIE

  14. Buon pomeriggio Samuele,
    il tuo blog è davvero utilissimo.
    Ti chiedo una gentilezza, avrei un calcolo SE da eseguire con le seguenti caratteristiche:

    La colonna H riporta una variabile in percentuale. avrei bisogno sulla casella di fianco di far si che a seconda delle seguenti regole venda riportata la dicitura 1 oppure 2 o in alternativa 3 :

    0/50%=1
    50/80%=2
    80/100%=3

    Ti ringrazio in anticipo !

  15. Grazie!

    Il tuo SE potrebbe essere =SE(H2<=50;1;SE(H2<=80;2;3)) Adattala rispetto ai valori che effettivamente hai nelle celle...non se hai il semplice rapporto (valori da 0 a 1) oppure proprio i valori percentuali

  16. Tutto perfetto ! Era in percentuale, ma con una piccola modifica ho risolto.

    Sempre gentilissimo e disponibilissimo !

  17. Ciao Avrei una domanda al quale non riesco a trovare risposta.
    Spero mi possa aiutare qualcuno

    Ho una cella nel quale c’è il nome del prodotto.
    All’interno del nome del prodotto ci sono svariate parole naturalmente. Faccio un paio di esempi cosi da poter essere più chiaro possibile.

    riga 1 cella B1: Braccioli gonfiabili Frozen eta +3 anni
    riga 2 cella B2; Giochi Preziosi – Braccioli Spiderman gonfiabili età +3 anni

    Avrei bisogno di una funzione che mi permettesse di scrivere nella celle J1 “Femmina” se trova la parola Frozen e “Maschio” se trova la parola Spiderman
    Stesso dicasi per la riga 2, riga 3, riga 4 ecc…..
    Grazie

  18. Buonasera Samule,
    Complimenti per i tutorial, estremamente chiari e concisi, ho provato a spulciare annche i video ma non ho trovato la solouzione al mio problemino…
    Ho una tabella su un foglio secondario con un elenco di province, sul principale vorrei che se in una colonna una delle province mi vinere riportata excel mi restituisca il testo A, altrimenti nulla.
    Al momento la mia formula funziona solo se riporto le provincie nell’ordine esatto in cui sono scritte nella tabella sul foglio secondario, se poi provo a trascinare la formula SE nel foglio principale non funziona per nulla…
    Help Me…
    Roberto

  19. Ciao Ivan.

    La formula potrebbe essere:
    =SE(NON(VAL.ERRORE(RICERCA(“Frozen”;B1)));”Femmina”;SE(NON(VAL.ERRORE(RICERCA(“Spiderman”;B1)));”Maschio”;””))

    Due SE annidati. Il primo ha come test la verifica se c’è la parola Frozen (fatta con il RICERCA, la quale restituisce errore se non trova la stringa), nel se_falso del primo SE c’è il secondo SE.

    Fammi sapere se ti può andare bene. Ciao!

  20. Caro Samuele, grazie per la tua disponibilità.
    Nella cella A1 ho € 10
    Nella cella A2 ho € 20
    Nella cella A3 vorrei che :
    – se A2 inf A1 scrivesse € 0
    – se A2 maggiore di A1 scrivesse la risultante di A2-A1
    Grazie 1k ed auguri di buon anno!!
    Riccardo

  21. Ciao Riccardo. Grazie, auguri anche a te.

    Se hai scritto =SE(A2>A1;(A2-A1);) non vedo errori. Controlla se nelle celle A1 e A2 hai effettivamente solo 10 e 20 o c’è altro. Se vuoi mandami il file.. samuele@amicoexcel.it

  22. Caro Samuele,
    tutto risolto.
    Complimenti , tutto molto utile.
    Grazie 1k !
    Riccardo

  23. Buongiorno,
    ma se io dovessi cercare un valore >500 e farmi restituire un testo e invece dove il valore non è >500 lasciare il valore che c’è è fattibile?

    Grazie
    Valeria

  24. Buonasera Valeria,
    il tuo SE potrebbe essere qualcosa tipo =SE(A2>500;”tuo_testo”;A2).
    Se il valore non è maggiore di 500 allora riscrivi il valore stesso.

  25. Buongiorno,
    avrei bisogno di ottenere questo risultato : se il valore di una cella (es. D4) è pari a 0,00 sostituiscilo con il valore della cella soprastante (es. D3). Come posso fare?
    Grazie mille
    Rossana

  26. Buongiorno,
    non riesco a capire come inserire una formula…le spiego.
    ES:
    cella A1 scritta ALTO, cella B1 scritta ALTO, vorrei che nella cella C1 uscisse una scritta tipo DA VENDERE
    mentre
    se nelle celle A e B ci fosse scritto BASSO la C1 dicesse DA SCARTARE
    e nel caso di ALTO BASSO, C1 dicesse DA CONTROLLARE
    spero di essermi spiegato

    Non so se quello che sto chiedendo è oggetto di ciò che state discutendo in questa pagina ma mi farebbe un favore enorme se mi potesse aiutare

    Grazie infinite

  27. Ciao Alessandro.

    Vedo due strade:

    1) SE annidati con all’interno la E
    =SE(E(A1=”alto”;B1=”alto”);”da vendere”;SE(E(A1=”basso”;B1=”basso”);”da scartare”;”da controllare”))

    2) un CERCA.VERT
    costruendo una matrice tabella, ad esempio in I1:J4, fatta così
    altobasso da controllare
    bassoalto da controllare
    bassobasso da scartare
    altoalto da vendere

    la funzione potrebbe essere
    =CERCA.VERT(A1&B1;I$1:J$4;2;0)

    Fammi sapere. Ciao!

  28. Ciao Samuele,
    scusa se disturbo ma avrei necessita di fare un’operazione complessa su excel.
    In una cella (M83) ho scritto una funzione tipo =SE(G83<=14,5;"0";SE(G83<=24,5;"100";SE(G83=34,5;”550″))))….bene funziona! Fin qui tutto semplice (immagino avrei potuto scrivere una formula più semplice…ma…non importa).
    Tuttavia il mio quesito non è terminato. Devo fare un altro controllo, cioè:
    se il valore della cella della stessa riga (F83) è > del risultato della formula scritta in M83 di cui sopra allora scrivi il contenuto di F83 altrimenti lascia il risultato ottenuto dalla formula .
    Aiuto!!! 😮
    Non è che mi aiuteresti. Grazie100000

  29. Buongiorno Samuele

    complimenti per i tutorial.

    La mia domanda è la seguente:
    supponiamo di avere in A1 un valore prefissato, in A2 un valore che cresce progressivamente. È possibile, nel momento in cui A2 diventa = o > di A1, saltare alla cella sucessiva A3 e proseguire il conteggio ?
    Grazie e buona giornata.
    Marco.

  30. Ciao!

    Aggiungerei un SE davanti…

    La tua originale è
    =SE(G83<=14,5;"0";SE(G83<=24,5;"100";SE(G83=34,5;”550″)))) potresti aggiungere =SE(F83>(SE(G83<=14,5;0;SE(G83<=24,5;100;SE(G83=34,5;550))));F83;SE(G83<=14,5;0;SE(G83<=24,5;100;SE(G83=34,5;550)))) però occhio alle virgolette sui numeri.. toglile se vuoi risultati numerici, altrimenti saranno testuali

  31. Grazie tanto,da 4 lezioni non ho capito il commando ma grazie a te l’ho capito subito.Ti stimo tanto.

  32. buongiorno, ti ringrazio per gli esempi che ho cercato di comprendere, ma fino ad ora non sono ancora riuscito a fare quello che mi serviva a me; provo a spiegarti

    ho in una cella un valore (risultato di una somma fra diverse celle) che può teoricamente andare da 5 a 600 ed il valore entro il quale lo vorrei far visualizzare non deve superare il120
    ho provato a fare questo =SE(M1>600;SE(M1>480;SE(M1>360;SE(M1<240;SE(M1<120);M1-120;M1)
    per riportare il valore entro il 120 e non superiore, ma mi da errore.
    Grazie per la spiegazione che riuscirai a darmi.
    buona giornata
    UGO

  33. Buongiorno Ugo. Non mi è chiaro perché nella formula vai a valutare 480, 360, 240 ecc. Forse manca qualche info su questo.
    Con =SE(M1>120;M1-(M1-120);M1) faresti vedere il numero se inferiore a 120 o lo imposteresti a 120 se superiore

  34. Buon giorno Samuele

    Chiedo il tuo aiuto in quanto non riesco a scrivere una formula.
    Ho necessità di riempire una cella in base al riempimento di un’altra. Ad esempio:
    Se nella cella A1 viene inserita una A, nella cella B1 deve comparire automaticamente 10.
    Se nella cella A1 viene inserita una B, nella cella B1 deve comparire automaticamente 9.
    Se nella cella A1 viene inserita una C, nella cella B1 deve comparire automaticamente 8.. e così via.
    Per ora ho scritto solo questo pezzo: =SE((C2=”A+”);”10″) ma non riesco ad andare avanti.
    Spero possa aiutarmi.
    Ti ringrazio in anticipo.
    Nicola

  35. Ciao Nicola.

    Alcune soluzioni che mi vengono in mente:

    1) funzione SE annidata

    =SE(A1=”A”;10;SE(A1=”B”;9;SE(A1=”C”;8;7)))
    al posto del 7 inserisci un altro SE con la stessa logica dei primi… e via via fino a prendere in considerazione tutti i valori

    2) se hai una versione di Excel che ha la funzione PIÙ.SE
    =PIÙ.SE(A1=”A”;10;A1=”B”;9)
    aggiungendo dopo il 9 tutte le altre condizioni

    3) sfruttando la funzione CODICE, che restituisce il codice in base al set di caratteri installato
    =10+65-CODICE(A1)

    4) creando una tabellina con con lettere nella prima colonna e numeri nella seconda,
    un CERCA.VERT

    Fammi sapere. Ciao!

  36. Buonasera ,
    Grazie per gli esempi esposti , volevo chiederle un aiuto in merito ad una funzione che non riesco a trovare.
    in una casella vorrei scrivere un valore numerico es da 1 a 10 e far colorare la casella adiacente di un colore corrispondente , 10 colori diversi a mia scelta che cambieranno a secondo il valore numerico posto nella casella numerica.
    Grazie anticipatamente e buona serata

  37. Buonasera,
    volevo chiederle un aiuto, sto svolgendo un problema dove mi chiede:
    Se l’ultima lettera del nome è “a” scrivere “donna”, altrimenti “uomo” (utilizzare la funzione Destra per trovare l’ultima lettera)
    come devo impostare la formula?
    Grazie in anticipo

  38. Buonasera Antonella,

    =SE(DESTRA(a2)=”a”;”donna”;”uomo”)

    Nel caso di presenza di spazi:
    =SE(DESTRA(ANNULLA.SPAZI(a2))=”a”;”donna”;”uomo”)

  39. Chiarissimo grazie mille.
    Ora mi trovo nella casella successiva dove praticamente devo svolgere questo: se è “idoneo/a” e “uomo” scrivi “attore”, altrimenti “respinto”. Se è “idoneo/a” e “donna” scrivi “attrice” , altrimenti ” respinta” (usare SE come funzione principale e al suo interno). Ho provato così:
    =SE(E(K2=”idoneo/a”;L2=”uomo”);”attore”;”respinto”);SE(E(K2=”idoneo/a”;L2=”donna”);”attrice”;”respinta”)
    ma mi esce errore

  40. Ciao Samuele, ho bisogno di un aiuto. Devo inserire una funzione in un contesto di questo tipo: se nella casella A1 è inserita la lettera A restituiscimi il valore 1, se la lettera B, il valore 2, se la lettera C il valore 3 ecc… Quale funzione devo utilizzare? Ho provato con la funzione =SE, ma non mi funziona su più di una lettera. Illuminami… 🙂 Grazie mille

  41. Ciao Andrea. Utilizzerei il CERCA.VERT.

    Puoi costruirti una tabella su cui cercare, formata da due colonne.
    Nella prima scrivi A, B, C, ecc. Nell’altra 1, 2, 3.

  42. Ciao Complimenti per il sito
    Avrei la necessità di cambiare il colore di riempimento di una cella nel caso la cella contenga due testi specifici per esempio : “Dom” o “Sab” sono riuscito utilizzando la formattazione condizionale, ma funziona solo per un testo non riesco a fare OR dei due.

    Grazie in anticipo

  43. Salve avrei bisogno di un aiuto:
    ho impostato una cella a tendina con 5 giudizi, pieno e consapevole, pieno, buono, parziale, scarso;
    vorrei impostare in una cella una formula in cui se nella la cella a tendina fosse selezionata pieno e consapevole vorrei che mi comparisse il numero 5, se pieno il numero 4, se buono il numero 3, ect.. come posso fare? ho provato con il se ma non riesco
    grazie anticipatamente

  44. Salve Rita. Farei così:

    =SE(A2=”pieno e consapevole”;5;SE(A2=”pieno”;4;SE( ecc. ecc. )))

    oppure

    =PIU’.SE(A2=”pieno e consapevole”;5;A2=”pieno”;4;ecc.

  45. Buongiorno Samuele, un aiuto cortesemente:
    Utilizzando la funzione Se considerando una tavella avente 2 colonne,sulla prima A 5 righe aventi nomi, sulla seconda B, in corrispondenza del nome un valore.
    La formula deve restituire il nome riferito a chi ha il voto più alto. Es.: Mario

  46. Buongiorno Walter,

    con la funzione MAX ci si potrebbe trovare il valore più alto. Con le funzioni INDICE e CONFRONTA ci si potrebbe trovare il nome. Tipo:
    =INDICE(A2:A10;CONFRONTA(MAX(B2:B10);B2:B10;0))

  47. Buongiorno Samuele,
    ho un piano di ammortamento di un mutuo, con una colonna riferita alle scadenze delle rate ed una riferita al capitale residuo dopo il pagamento della rata corrispondente. Ho bisogno di una formula che prenda dalla colonna il valore del capitale residuo alla data odierna in automatico. Grazie.Complimenti per il sito.

  48. Alla fine ci sono arrivato così VLOOKUP(TODAY();intervallo intera tabella;colonna capitale residuo)

  49. Complimenti Samuele per la tua competenza.
    Volevo chiederti un aiuto.
    Ecco il mio problema: vorrei capire se esiste una funzione “logica” che ti permette di “inserire” in automatico un valore in una cella di excel se sono presenti CONTEMPORANEAMENTE determinati “valori” in altre DUE celle.
    In altre parole se nella cella “A” è presente il valore “x” e nella cella “B” è presente CONTEMPORANEAMENTE il valore “y”, allora nella cella “C” excel inserirà in automatico il numero “z”.
    Nello specifico io vorrei ottenere questo:

    cella in Colonna A: può assumere due valori H o L.
    cella in Colonna B: può assumere due valori H o L.
    cella Colonna C: voglio che mi dia in “automatico” uno dei seguenti numeri in base alle possibili combinazioni delle colonne A e B, ossia:

    Col A. e Col.B …Col. C
    H e H …. 1
    H e L …. 2
    L e H …. 3
    L e L …. 4

    Ho letto la sintassi della regola “SE” ma non mi sembra faccia al caso mio. O mi sbaglio?

    Grazie mille in anticipo per la tua disponibilità.
    Anna

  50. Ciao Anna.

    Puoi usare la funzione E nel test del SE.

    Quindi =SE(E(A2=”H”;B2=”H); 1;SE(E(A2=”H”;B2=”L);2;SE(ecc.)

    Qui trovi il mio tutorial:
    https://www.amicoexcel.it/funzione-e/

    Oppure, come alternative, puoi dare un’occhiata alle funzioni PIU’.SE o CERCA.X

  51. Buongiorno.
    Sto provando in tutti i modi a scrivere una formula SE che mi aiuti in questo:
    Colonna A -> dei termini in italiano
    Colonna B -> in B1 vorrei scrivere FRA (per francese) o ENG (per inglese)
    La funzione SE dovrebbe essere: SE in B1 c’è FRA, restituisci (parola in francese), altrimenti (parola in inglese).
    Poi a seconda della traduzione che mi serve (se inglese o francese), in B1 andrò a scrivere FRA o altro.
    È corretta impostata come segue?
    A1: vuoto
    A2: comincia l’elenco delle parole in italiano
    B1: FRA (o altro)
    B2: =SE(B1=fra;chassis;undercarriage)
    Che sarebbe: se in B1 c’è FRA, restituiscimi chassis, altrimenti undercarriage.
    Vi prego, aiutatemi!

  52. Ciao Marta. Sì corretto. Aggiungici solo i doppi apici, perché sono criteri testuali:

    =SE(B1=”fra”;”chassis”;”undercarriage”)

    Curiosità: perché non valuti la creazione di un elenco con termini italiano e accanto francese, poi un elenco con tenrmini italiano e accanto inglese.?
    Poi con un CERCA.VERT in B2: =CERCA.VERT(A2;se(b1=”fra”;D:E;G:H);2;0) Dove D:E è l’intervallo dove costruisci il primo elenco italiano francese…G:H italiano inglese.
    Non voglio cmq complicarti la vita… è che in generale mi sembrerebbe un modo di lavorare più elastico… anche se poi va calato nel tuo contesto.

  53. Buonasera.
    Ho due colonne: in una dei nomi che si possono anche ripetere e nell’altra un prodotto che può cambiare.
    Excel è in grado di evidenziarmi quei nomi che sono associati ad un cambio di prodotto nella colonna B?
    In pratica, mi serve capire se Excel riesce a filtrare solo quei nomi presenti nella colonna A associati ad una variazione di prodotto nella colonna B.
    Se Giuseppe (colonna A) è sempre associato alla mela (colonna B), non mi interessa; mi interessa Giuseppe se prende una volta la mela, una volta la pera, ecc.

  54. Ciao Samuele,

    necessitavo di filtrare nomi maschili e femminili per impostare una lettera con dato variabile “Egr. Sig.” o “Gent.le Sig.ra”. Ho trovato la formula spiegata chiaramente!!!! A differenza di altri siti visitati prima: troppo complicati nelle spiegazioni
    MI sono imbattuta casualmente su questo sito, e ci tornerò sicuramente ogni volta che ne avrò necessità.
    Mille grazie e i miei più calorosi complimenti.
    Tatiana

  55. Buongiorno, ho creato una funzione PIU.SE ma non riesco a copiarla correttamente sul resto delle celle .Quale suggerimento mi da ?
    Grazie

  56. Salve, cercavo una formula semplice per potermi calcolare le ore lavoro in base ai turni e riposi Malattie e ferie, ma non riesco con la formula.
    Vorrei fare una cella che se metto sulla cella A1 il num. 1 (primo turno), sulla cella A2 mi appare 8 (che sarebbero ore) sempre nella stessa cella A1 se metto il num. 2 sulla cella A2 mi appare 8, se metto 3 appare 7,5 (sempre ore), però se metto sulla cella A1 R (riposo) sulla cella A2 appare 0, se su A1 metto F sulla cella A2 apre scritto ferie e se metto M appare Malattia e così via.
    Praticamente sulla stessa cella in base a ciò che inserisco sulla cella a fianco mi appaia la formula.
    Spero sono stato chiaro e ringrazio anticipatamente chi mi sa dire la formula come farlo.

  57. Ciao Salvatore. Dovresti usare la funzione PIU’.SE oppure usare dei se annidati. Rispetto a questa secondo metodo trovi info sulla pagina dedicata al SE doppio.
    Nella cella A2 sarà qualcosa tipo =SE(A1=1;8;SE(A2=2;8;SE(A2=3;7,5; ecc.

  58. Ciao Samuele, molto chiaro nelle spiegazioni. Non trovo però la soluzione al mio problema.
    Ho due tabelle, nella prima, indico con il codice ROL il valore 1, ROL2 il valore 2,ROL3 il valore 3, così via fino a ROL8 il valore 8; i valori si vanno a sommare in una determinata casella di una seconda tabella. I codici vanno elencati i una colonna di max 31 celle.
    Ho usato la formula =CONTA.SE(E3:E33;”ROL”) ma così individuo solo la scritta rol ma non tutto il resto.
    Ho usato la formula =SE(E3=”rol2″;2;0)+SE(E4=”rol2″;2;0)+SE(E5=”rol2″;2;0)+SE(E6=”rol2″;2;0)+SE(E7=”rol2″;2;0)+SE(E8=”rol2″;2;0)+SE(E8=”rol2″;2;0)+SE(E10=”rol2″;2;0)+SE(E11=”rol2″;2;0)+SE(E12=”rol2″;2;0)+SE(E13=”rol2″;2;0)+SE(E14=”rol2″;2;0)+SE(E15=”rol2″;2;0)+SE(E16=”rol2″;2;0)+SE(E17=”rol2″;2;0)+SE(E18=”rol2″;2;0)+SE(E19=”rol2″;2;0)+SE(E20=”rol2″;2;0)+SE(E21=”rol2″;2;0)+SE(E22=”rol2″;2;0)+SE(E23=”rol2″;2;0)+SE(E24=”rol2″;2;0)+SE(E25=”rol2″;2;0)+SE(E26=”rol2″;2;0)+SE(E27=”rol2″;2;0)+SE(E28=”rol2″;2;0)+SE(E29=”rol2″;2;0)+SE(E30=”rol2″;2;0)+SE(E31=”rol2″;2;0)+SE(E32=”rol2″;2;0)+SE(E33=”rol2″;2;0) ma così individuo solo ROL2 (o ROL3 e così via. Ma non mi permette di sommare i vari valori un una casella. (lo posso ottenere facendo la somma di tutti i risultati ottenuti)
    Esiste un metodo “più veloce” per avere la somma dei miei ROL?
    Grazie della tua disponibilità.

  59. Ciao Antonio.

    Io vedo queste due soluzioni. Una un po’ “grezza”, basata su CONTA.SE, ed una più elegante, basata su forme matriciali.

    Prima soluzione:
    =CONTA.SE(E3:E33;”rol”)+2*CONTA.SE(E3:E33;”rol2″)+3*CONTA.SE(E3:E33;”rol3″)+ ecc..

    Seconda soluzione:
    Perché funzioni dovresti scrivere ROL1 al posto di ROL

    =SOMMA(–DESTRA(E3:E13;1)) in forma matriciale… vuol dire che non devi confermare con INVIO ma con CTRL+SHIFT+INVIO

    Ciao!

  60. Salve,
    Intanto grazie perché questo sito è uno strumento che uso spesso e mi aiuta tanto nel lavoro;
    avrei gentilmente bisogno di un ‘indicazione.
    Ho un file con un elenco di abbonamenti ed una colonna con la data di scadenza di ognuno.
    Vorrei creare una colonna dove per ogni abbonamento sia indicato se , rispetto alla data dell’aggiornamento settimanale, l’abbonamento é :A.scaduto B.a scadere tra 3 /12 mesi C. non scaduto D.a scadere entro 3 mesi
    Spero di essere stata abbastanza chiara..ho provato con la formattazione condiz ma dava risultati contrastanti e con la diff tra date compariva Valore..
    Grazie in anticipo per l’aiuto che mi potra fornire.
    Un saluto
    S.

  61. Buon giorno, vorrei sapere se la formula SE funziona solo con i numeri o anche con le parole. Ho provato ad inserire la formula guidata con SE e nella casella del test ho inserito una cella che fa riferimento a un nome e mi segna errore perché non è un valore. Ora ti spiego qual è il mio problema. Nel file del bilancio famigliare ho due colonne dove devo inserire i dati che le vorrei rendere più agili. Nella colonna A ci sono celle con tendina a discesa con 4 voci, “casa, auto, personali, ecc..”. Ogni voce ha delle sotto voci. Nella colonna B ci sono le celle a discesa con tutte le sotto voci che sono tante. Volevo sapere se è possibile nelle cella della colonna B richiamare l’elenco della voce che ho definito nella cella della colonna A? Esempio SE A1 = casa inserisci l’elenco riferito a casa che avrò messo nella colonna M1:M6. Non so sono riuscito a spiegare cosa vorrei fare. Ringrazio per la tua disponibilità.

  62. Ciao Stefania. Grazie a te, mi fa molto piacere che il blog ti sia d’aiuto.

    Per la tua necessità va bene la formattazione condizionale se vuoi colorare. Oppure la funzione SE se vuoi scrivere “scaduto”, “scadere tra..” ecc.

    Le regole da creare, sia nella formattazione che nel SE, possono sfruttare la funzione OGGI()… quindi, ad esempio, SE(data<=OGGI();"scaduto".... oppure SE(data>OGGI();”non scaduto”…. SE(E(data>OGGI();data<=OGGI()+90);"a scadere entro 3 mesi... Se poi hai problemi mandami le formule in un file a samuele@amicoexcel.it

  63. Ciao Giacomo. La funzione SE funziona anche con il testo, con l’accortezza di aggiungere gli apici.. esempio: SE(A2=”tuo_testo”).

    Quel che mi descrivi in realtà mi fa pensare a delle tendine collegate tra loro… Prova a vedere il mio articolo dedicato alla tematica dei menu a tendina collegati

  64. Grazie mille per la rapidità della risposta. Ho letto il tuo articolo sull’argomento ed è stato molto interessante. Non conoscevo assolutamente la funzione “indiretto”. mentre la funzione convalida dati la usavo solo per creare il menu a tendina senza saper per altre funzioni. Per curiosità, anche con la formula SE è possibile fare il menu a tendina collegati, anche se più complicato? Ancora grazie mille. Saluti

  65. Buongiorno,
    vorrei sapere se e’ possibile utilizzare la funzione se con il colore di una cella. mi spiego meglio.
    Nel momento in cui verra’ colorata di verde una cella della colonna A nella cella della colonna B il numero 1 deve diventare 0.
    Grazie anticipatamente

  66. Possibile scrivendo del codice VBA. La funzione SE non è in grado di verificare la formattazione di una cella.

  67. Grazie mille per la tua risposta.. e’ possibile avere un esmpio?
    grazie ancora

  68. Ciao Samuele e grazie
    io vorrei utlizzare il SE e ALLORA
    mi spiego meglio :
    se (una cifra uguale a zero) allora inserisci altra cifra (di un’altra casella)
    se non uguale a zero inserisci quella (cifra), spero di essermi spiegato , come fare?

  69. Buongiorno Samuele,
    ho una tabella con nome cliente, tipo appuntamento ,data ,ora.
    Vorrei che questa tabella compilasse in automatico un’agenda settimanale.
    Sai darmi qualche dritta?

    Grazie.

  70. Buongiorno Marco.

    Secondo me dovresti utilizzare VBA. Dopo aver inserito una riga con un pulsante dovresti scrivere il dato all’interno della tua agenda. Non banale se non conosci VBA.

  71. Buongiorno,
    ho una lista di oggetti nelle celle e se il valore della cella e maggiore di 0 deve ricopiare la cella.(=SE(F11>=1;A11;””))
    A questo punto se la cella contiene il testo che ho copiato deve inserirla in un altra cella in ordine .
    Il problema è che ci possono essere delle celle vuote sapete indicarmi la funzione da scrivere
    grazie

  72. Salve Massimo.

    Ok la prima parte.
    La seconda non mi è chiara:
    “A questo punto se la cella contiene il testo che ho copiato deve inserirla in un altra cella in ordine .”

  73. Buon giorno Samuele,
    ho letto le tue risposte ai vari interrogativi che ti fanno e le ho trovate chiare. Vorrei chiederTi se con la formula SOMMA.SE si possono inserire valori negativi. Mi spiego meglio, la formula che ho inserito funziona bene se inserisco valori positivi, quando inserisco un valore negativo, mettendo il meno davanti al numero toglie un valore doppio di quello che inserito. Bisogna modificare la formula per fare accettare valori negativi? La formula è questa: =SOMMA.SE($F$8:$F$498;”R”;$D$8:$D$498) dove F è la colonna della condizione e D la colonna dei valori. Ti ringrazio per la tua disponibilità.

  74. Molto utile il tutorial, vorrei chiederti un aiuto. Mi servirebbe capire come poter scrive la funzione se per fare un’operazione un pò complessa. In una colonna C ho un testo e può esserci scritto “x” o “y” o “z”. Se in quelle 30 righe c’è scritto “x” allora mi serve la media dei punteggi (che ho in una colonna “e”) però gli altri punteggi, rispettivamente delle Y e delle Z non devono essere inclusi nella media.
    Esempio
    C … … …. E
    x 1
    x 3
    y 6
    y 5
    z 3
    x 8
    vorrei costruire una tabella a parte per fare la media di tutte le X, le Y e le Z. Per esempio vorrei che mi facesse la media dei punteggi in colonna “E” se nella colonna C c’è scritto X (quindi in questo caso la media di 1 3 e 8), ma non prendere i punteggi della colonna E se nella colonna C c’è scritto Y o Z. E così via anche con le “Y” e delle “Z”.

  75. Ciao Evelina,

    potresti usare la funzione MEDIA.SE…

    =MEDIA.SE(C:C;”x”;E:E)
    Calcola la media della colonna E ma solo per i valori che nella colonna C sono uguali a “x”.

    Al posto di “x” nella formula puoi ovviamente far riferimento ad una cella dove hai scritto x, y oppure z:
    =MEDIA.SE(C:C;G2;E:E)

    Qui trovi la guida ufficiale sulla funzione MEDIA.SE di Excel:
    https://support.microsoft.com/it-it/office/media-se-funzione-media-se-faec8e2e-0dec-4308-af69-f5576d8ac642

  76. Buongiorno ho un problema con la funzione logica “SE”: cella E1 Deve restituire il valore delle uscite future cioè C8-E8. Ma se la cella E5 si mette il Valore “0” (zero a numero, quindi è una spesa che non avverra o sara parziale) il corrispondente valore della C5 andra a sottrarre il valore intero della E1 ovvero andra a sottrarre la differenze tra C5 e E5. Lo stesso criterio si dovra applicare alla cella E1 per le righe 6 e 7 colonne C ed E.
    ————————————————————————–
    A B C D E
    —————————————————————————-
    1- s.do iniz : 5300 usciranno : 300
    nel mese
    2- saldo attuale: 5300 restano disponibili ?????
    ——————————————————————————
    3- da pagare pagato
    ——————————————————————————-
    5 100 casa
    6 100 utenze
    7 100 altro
    ————————————————————————–
    8 totale 300 ???
    ———————————————————————-
    A B C D E
    ————————————————————————–
    In attesa di Sua cortese attenzione la ringrazio in anticipo.

Comments are closed.